Power Tools for Macintosh/Power Tools for Macintosh (SoftBit)(1992).iso/Stacks/*S-Z/Script Stripper/Script Stripper v2.0/stack_-1.xml

Extensible Markup Language | 1993-06-05 | 12.2 KB | 20 lines

<?xml version="1.0" encoding="utf-8" ?>
<!DOCTYPE stack PUBLIC "-//Apple, Inc.//DTD stack V 2.0//EN" "" >
<stack>
    <name>in.0</name>
    <id>-1</id>
    <cardCount>1</cardCount>
    <cardID>2837</cardID>
    <listID>4613</listID>
    <cantModify><false /></cantModify>
    <cantDelete><true /></cantDelete>
    <cantAbort><false /></cantAbort>
    <cardSize>
        <width>512</width>
        <height>342</height>
    </cardSize>
    <script>2.0

on openStack
hide menuBar
aboutTheStripper
put line 1 of script of this stack into bg fld "the version of"
end openStack

on closeStack
show menuBar
end closeStack

on aboutTheStripper
put "About Script Stripper..." into menuItem 1 of menu "Apple" with ¬
menuMsg "about"
end aboutTheStripper

on about
-- use "Hard Spaces" (eg: <Option-Space>) to create formatted
-- output in a dialog box
answer "    "&quote&"Script Stripper,"&quote&&"a HyperCard script"¬
&&"            extraction utility."¬
&&" _____________________________________"¬
&&"        ©1993, Donald J. Winiecki"¬
&&"         5202 Bangor Ave., H 204"¬
&&"                      Lubbock, TX. 79414"¬
&&"             {806} 792-5253" with "More..." or "Done"
if it = "More..." then
lock screen
show cd fld "Stripper Help"
show cd btn "Hide Stripper Help"
set the hilite of cd btn "Hide Stripper Help" to true
set the scroll of cd fld "Stripper Help" to 533 -- go to specific point in "Help" field
unlock screen with scroll down
end if
end about

on checkIfCompactNeeded
-- keep the stack lean (copying & moving text builds LOTS of freespace)
-- this handler is from pp. 207 of "The Complete Book of HyperTalk 2, by Dan Shafer
put size of this stack into stackSize
put freeSize of this stack into freeSpace
if freeSpace > (.3 * stackSize) then -- if freeSpace exceeds 30% of stack's size
answer "  "&quote&"Script Stripper"&quote&&"should be compacted"¬
&&"          before we continue." with "Ok"
doMenu "Compact Stack"
end if
end checkIfCompactNeeded

on whereItsSaved
global thisStack, stackNameTruncated_G
if stackNameTruncated_G is not empty then
-- if the ".strip" file name had to be truncated •• (6/5/93)
answer "Scripts for:"&&quote&stackNameTruncated_G&quote&&"have been saved in"¬
&&"the"&&quote&"~Script Stripper Textfiles"&quote&&"folder"¬
&&"as:"&&quote&stackNameTruncated_G&".strip."&quote with "Oh Boy !"
else
answer "Scripts for:"&&quote&thisStack&quote&&"have been saved in"¬
&&"the"&&quote&"~Script Stripper Textfiles"&quote&&"folder"¬
&&"as:"&&quote&thisStack&".strip."&quote with "Oh Boy !"
end if
end whereItsSaved

function underScore
-- declare and use a function instead of typing this thing every time
return "_____________________________________________________"
end underScore

on retrieveStackScript
global thisStack_G, thisStack, stackNameTruncated_G
push card -- remember where to come back to
put empty into thisStack
put empty into thisStack_G
put empty into stackNameTruncated_G

-- find the short name of the "Script Stripper"
repeat with i = number of chars in long name of this stack down to 1
set cursor to busy
-- keep the last item in the path statement
if char i of long name of this stack = ":" then exit repeat
put char i of long name of this stack before temp
end repeat

-- establish the path to where the "Stripped" script will be stored {stored in 'filePath'}
-- (!!!!user should not change file/folder names or location of the "...Textfiles" folder)
repeat with i = 8 to (number of chars in long name of this stack - (number of chars in temp + 1))
set cursor to busy
put char i of long name of this stack after filePath
end repeat

-- request user to maneuver to and identify stack to be stripped
-- full path to the desired stack is put into "it"
answer file "Strip which stack's scripts ?" of type "STAK"

-- if user decides not to do it then bail out...
if it is empty then
answer " Script Stripping Operation Aborted!" with "Whew !"
exit retrieveStackScript
end if

-- store the full path name of the stack to be stripped into global variable 'thisStack_G'
put it into thisStack_G

-- establish the name of the textfile to be created for this stripping session
repeat with i = number of chars in thisStack_G down to 1
set cursor to busy
if char i of thisStack_G = ":" then exit repeat
put char i of thisStack_G before thisStack
end repeat

-- write my tag line into the holder variable (strippingHolder)
put quote&"Script Stripper"&&line 1 of script of this stack&quote&&"HyperCard"¬
&&"script extractor."&return&"©1992, 1993. Donald J. Winiecki, all rights reserved."&return ¬
&"‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû‚àû"&return&return into strippingHolder

set lockMessages to true
lock screen
go stack thisStack_G

-- write the selected stack's script after holder variable
put "• Name of Stack:"&&quote&thisStack&quote&return after strippingHolder

-- write some stack statistics
put the userLevel into it
if it = 1 then put "1;"&&quote&"Browsing"&quote into it
if it = 2 then put "2;"&&quote&"Typing"&quote into it
if it = 3 then put "3;"&&quote&"Painting"&quote into it
if it = 4 then put "4;"&&quote&"Authoring"&quote into it
if it = 5 then put "5;"&&quote&"Scripting"&quote into it
put "• Size of Stack:"&&size of this stack / 1000&&"KB."&return after strippingHolder
put "• Free Space in Stack:"&&the freeSize of this stack / 1000&&"KB."&return after strippingHolder
put "• User Level of Stack:"&&it&return&return after strippingHolder
put "• Date of Stripping:"&&the long date&return after strippingHolder
put "• Time of Stripping:"&&the time&return&return after strippingHolder
put "◊ ◊ Starting scripts of Stack:"&&quote&thisStack&quote&" ◊ ◊"&return&return after strippingHolder
put "• • Script of Stack:"&&quote&thisStack&quote&" • •"&return after strippingHolder
put underScore()&return after strippingHolder
if script of stack thisStack_G is not empty then
put script of stack thisStack_G after strippingHolder
else
put "* No script at the Stack Level" after strippingHolder
end if
put return&return after strippingHolder

go to first cd of stack thisStack_G

repeat with i = 1 to the number of bgs
go bg i
set cursor to busy
put empty into j
put empty into k

put "• ◊ Scripts of Background"&&i&";"&&quote&short name of this bg¬
&quote&return after strippingHolder
put underScore()&return after strippingHolder
if script of bg i is empty then
put "* No script for this Background" after strippingHolder
else
put script of bg i after strippingHolder
end if
put return&return after strippingHolder

repeat with k = 1 to number of bg btns
set cursor to busy
put "• Script of Background Button:"&&k&";"&&quote&short name of bg btn k¬
&quote&&"of Background"&&i&return after strippingHolder
put underScore()&return after strippingHolder
if script of bg btn k is empty then
put "* No script for this Background Button" after strippingHolder
else
put script of bg btn k after strippingHolder
end if
put return&return after strippingHolder
end repeat

repeat with j = 1 to number of bg flds
set cursor to busy
put "• Script of Background Field"&&j&";"&&quote&short name of bg fld j¬
&quote&&"of Background"&&i&return after strippingHolder
put underScore()&return after strippingHolder
if script of bg fld j is empty then
put "* No script for this Background Field" after strippingHolder
else
put script of bg fld j after strippingHolder
end if
put return&return after strippingHolder
end repeat

repeat with L = 1 to number of cds of bg i
go cd L of bg i
put empty into m
put empty into n

set cursor to busy
put "• Script of Card:"&&L&";"&&quote&short name of cd L of this bg¬
&quote&&"of Background"&&i&return after strippingHolder
put underScore()&return after strippingHolder
if script of cd L of this bg is empty then
put "* No script for this Card" after strippingHolder
else
put script of cd L of this bg after strippingHolder
end if
put return&return after strippingHolder

repeat with n = 1 to number of cd btns
set cursor to busy
put "• Script of Card Button:"&&n&";"&&quote&short name of cd btn n¬
&quote&&"of Card"&&L&&"of Background"&&i&return after strippingHolder
put underScore()&return after strippingHolder
if script of cd btn n is empty then
put "* No script for this Card Button" after strippingHolder
else
put script of cd btn n after strippingHolder
end if
put return&return after strippingHolder
end repeat

repeat with m = 1 to number of cd flds
set cursor to busy
put "• Script of Card Field:"&&m&";"&&quote&short name of cd fld m¬
&quote&&"of Card"&&L&&"of Background"&&i&return after strippingHolder
put underScore()&return after strippingHolder
if script of cd fld m is empty then
put "* No script for this Card Field" after strippingHolder
else
put script of cd fld m after strippingHolder
end if
put return&return after strippingHolder
end repeat
end repeat
end repeat

-- stacks with long names cause problems with "Script Stripper"
-- at this point in the handler. The handler has therefore been
-- designed to truncate long script names and store the stripped file
-- using a shortened version of the original stack name (the original
-- stack's name is not changed). •• (6/5/93)

if the number of chars in thisStack > 27 then -- file names limited to 31 char's here
put the number of chars in thisStack into nameThisLong
put char 1 to 10 of thisStack into stackNameTruncated_G
put "..." after stackNameTruncated_G
put char (nameThisLong - 10) to nameThisLong of thisStack after stackNameTruncated_G
end if

-- write the variable contents to the textfile named for the stack
if stackNameTruncated_G is not empty then -- if the stack name was too long
open file filePath&":"&"~Script Stripper Textfiles"&":"&stackNameTruncated_G&".strip"
write strippingHolder to file filePath&":"&"~Script Stripper Textfiles"&":"&stackNameTruncated_G&".strip"
close file filePath&":"&"~Script Stripper Textfiles"&":"&stackNameTruncated_G&".strip"
else
open file filePath&":"&"~Script Stripper Textfiles"&":"&thisStack&".strip"
write strippingHolder to file filePath&":"&"~Script Stripper Textfiles"&":"&thisStack&".strip"
close file filePath&":"&"~Script Stripper Textfiles"&":"&thisStack&".strip"
end if

pop card -- come back to where we left
unlock screen

if the number of chars in strippingHolder < 29900 then
-- only 30000 characters can be held in a HyperCard field
answer "Would you like to view the scripts for stack:"&&quote&thisStack&quote¬
&&"now?" with "Later" or "Yes"
if it = "Yes" then
lock screen
show cd pict
repeat with i = 1 to (number of cd btns - 1)
-- show all buttons except "Hide Help"
show cd btn i
end repeat
show bg fld "Editing Field"
hide bg btn "Go Home"
put strippingHolder into bg fld "Editing Field"
unlock screen with barn door open
else
whereItsSaved
end if
else
answer "The scripts for"&&quote&thisStack&quote&&"are"¬
&&"too long to view within the Script Stripper, use TeachText or your"¬
&&"word processor to open the file instead." with "Okay"

-- tell the user where the textfiles are saved
whereItsSaved
end if

set lockMessages to false
end retrieveStackScript</script>
    <background id="2747" file="background_2747.xml" name="Stripper bg 1" />
    <card id="2837" file="card_2837.xml" marked="false" name="Stripper cd 1" owner="2747" />
</stack>